Configuring Add-ins

Set root = CreateObject("FPC.Root")
Set isaArray = root.GetContainingArray()
Set attackDetection = isaArray.ArrayPolicy.AttackDetection
Set dnsFilter = isaArray.Extensions.ApplicationFilters.Item("{49FE2B2F-3BB4-495C-87C8-3890C3C35756}")
dnsFilter.Enabled = True
Set vpSets = dnsFilter.VendorParametersSets
On Error Resume Next
vpSets.Add "{D96C5E7F-5B13-4E1A-94A1-36CA7B54604E}", False, False
On Error Goto 0		 ' If a vendor parameters sets for DNS Filter already exists
vpSets.Item("{D96C5E7F-5B13-4E1A-94A1-36CA7B54604E}").Value("DNS_Intrusion_detection") = "1"
vpSets.Item("{D96C5E7F-5B13-4E1A-94A1-36CA7B54604E}").Value("DNS_Hostname_Overflow") = "1"
vpSets.Item("{D96C5E7F-5B13-4E1A-94A1-36CA7B54604E}").Value("DNS_Length_Overflow") = "1"
vpSets.Item("{D96C5E7F-5B13-4E1A-94A1-36CA7B54604E}").Value("DNS_Zone_Transfer") = "0"
vpSets.Save

Dim root
Dim ftpFilter
Dim vpSet
On Error Resume Next
Err.Clear
Set root = CreateObject("FPC.Root")
' Get the filter's administration object
Set ftpFilter = root.GetContainingArray.Extensions.ApplicationFilters("{680A928F-22B3-11d1-B026-0000F87750CB}")
If ftpFilter Is Nothing Then
	Wscript.Echo "FTP Access Filter ({680A928F-22B3-11D1-B026-0000F87750CB}) is not installed in array." 
	WScript.Quit
End If
' Get the vendor parameter set containing the filter's configuration.
Set vpSet = ftpFilter.VendorParametersSets.Item("{680A928F-22B3-11D1-B026-0000F87750CB}")
'If this vendor parameters set does not exist, create it.
If vpSet Is Nothing Then
	WScript.Echo "Adding a vendor parameters set ({680A928F-22B3-11D1-B026-0000F87750CB})"
	Err.Clear
	Set vpSet = ftpFilter.VendorParametersSets.Add("{680A928F-22B3-11D1-B026-0000F87750CB}",False)
	ftpFilter.VendorParametersSets.Save
End If
' Add the required parameter.
vpSet.Value("AllowReadCommands") = "USER PASS"
vpSet.Save

Sub ExportConfiguration(ruleName, fileName)
	const FilterGUID = "{f1076e51-bbaf-48ba-a2d7-b0875211e80d}"
	const Error_FileNotFound = &H80070002
	const ConfigParamName = "XML_POLICY"
	Dim rule, vpSets, vpSet
	Dim errorCode, errorDescript
	Dim xmlText
	Dim fso
	Dim file
	Set fso = CreateObject("Scripting.FileSystemObject")
	On Error Resume Next
	Set rule = rules.Item(ruleName)
	Select Case Err.Number
		Case Error_FileNotFound:
			WScript.Echo "The policy rule " & ruleName & " could not be found."
			WScript.Quit
		Case 0:
		Case Else
			' Add code to display the error.
			WScript.Quit
	End Select
	On Error GoTo 0
		 Set vpSets = rule.VendorParametersSets
	On Error Resume Next
	Set vpSet = vpSets.Item(FilterGUID)
	errorCode = Err.Number
	errorDescript = Err.Description
	On Error GoTo 0
	Select Case errorCode
		Case 0:
		Case Error_FileNotFound:
			WScript.Echo "The rule is using the default HTTP Filter configuration, which is not" & VbCrLf _ 
					 & "defined in a vendor parameters set and cannot be exported to an XML" & VbCrLf _ 
					 & "file."
			WScript.Quit
		Case Else
			Err.Raise errorCode,, errorDescript
	End Select
	xmlText = vpSet.Value(ConfigParamName)
	Set file = fso.OpenTextFile(fileName, ForWriting, True)
	file.WriteLine(xmlText)
	file.Close
	WScript.Echo "The configuration was exported successfully."
End Sub

Sub ImportConfiguration(ruleName, fileName)
	const FilterGUID = "{f1076e51-bbaf-48ba-a2d7-b0875211e80d}"
	const Error_FileAlreadyExists = &H800700B7
	Dim rule, vpSets, vpSet
	Dim errorCode, errorDescript
	Dim xmlText
	Dim fso
	Dim file

	Set fso = CreateObject("Scripting.FileSystemObject")
	On Error Resume Next
	Set rule = rules.Item(ruleName)
	Select Case Err.Number
		Case Error_FileNotFound:
			WScript.Echo "The policy rule " & ruleName & " could not be found."
			WScript.Quit
		Case 0:
		Case Else
			' Add code to display the error.
			WScript.Quit
	End Select
	On Error GoTo 0
	Set vpSets = rule.VendorParametersSets
	On Error Resume Next
	' Create a vendor parameters set for the HTTP Filter Web filter
	' in the vendor parameters sets collection of the specified rule.
	Set vpSet = vpSets.Add(FilterGUID, False)
	errorCode = Err.Number
	errorDescript = Err.Description
	On Error GoTo 0
	Select Case errorCode
		case 0:
		case Error_FileAlreadyExists:
			set vpSet = vpSets(FilterGUID)
		case Else
			Err.Raise errorCode,, errorDescript
	End Select
	Set file = fso.OpenTextFile(fileName)
	xmlText = file.ReadAll
	vpSet.Value(ConfigParamName) = xmlText

	rule.Save
	WScript.Echo "The configuration was imported successfully."
End Sub

Sub SetNewSize(newLimit)
	const FilterGUID = "{f1076e51-bbaf-48ba-a2d7-b0875211e80d}"
	const ConfigParamName = "XML_POLICY"
	const Error_FileAlreadyExists = &H800700B7
	Dim httpFilter, vpSets, vpSet, newVal
	Dim errorCode, errorDescript
	Dim root

	Set root = WScript.CreateObject("FPC.Root")
	Set httpFilter = root.GetContainingArray.Extensions.Webfilters.Item(FilterGUID)
	Set vpSets = httpFilter.VendorParametersSets
	On Error Resume Next
	Set vpSet = vpSets.Add(FilterGUID, False)
	errorCode = err.Number
	errorDescript = err.Description
	On Error GoTo 0
	Select Case errorCode
		Case 0:
		Case Error_FileAlreadyExists:
			Set vpSet = vpSets.Item(FilterGUID)
		Case Else
			Err.Raise errorCode,, errorDescript
	End Select
	newVal = "<Configuration MaxRequestHeadersLen="" " & newLimit & " ""/>"
	vpSet(ConfigParamName) = newVal 
	httpFilter.Save
	WScript.Echo "The maximum header length was set successfully."
End Sub