MoveUp Method of the IFPCUserAgentMappings Interface

Option Explicit
 
' Define the constant needed.
Const Error_TypeMismatch = &HD
const Error_InvalidParameter = &H80070057
 
Main(WScript.Arguments)
 
Sub Main(args)
	If(args.Count <> 1) Then
		Usage()
	Else
	 MoveUpMapping args(0)
	End If
End Sub
 
Sub MoveUpMapping(mappingId)
 
	' Create the root object.
	Dim root  ' The FPCLib.FPC root object
	Set root = CreateObject("FPC.Root")
 
	' Declare the other objects needed.
	Dim isaArray	' An FPCArray object
	Dim mappings	' An FPCUserAgentMappings collection
	' Get references to the array object and
	' the User-Agent mappings collection.
	Set isaArray = root.GetContainingArray()
	Set mappings = isaArray.RuleElements.UserAgentMappings
 
	' Move up the specified User-Agent mapping.
	On Error Resume Next
	mappings.MoveUp(CInt(mappingId))
	If Err.Number = Error_TypeMismatch Then
		WScript.Echo "The Mapping parameter specified is not a number."
		WScript.Quit
	ElseIf Err.Number = Error_InvalidParameter Then
		WScript.Echo "The mapping specified cannot be moved or does not exist."
		WScript.Quit
	Else
		WScript.Echo "Moving the User-Agent mapping specified up..."
	End If
	On Error GoTo 0
 
	' Save the changes to the collection of User-Agent mappings.
	mappings.Save
	WScript.Echo "Done!"
End Sub
 
Sub Usage()
	WScript.Echo "Usage:" & VbCrLf _
		& "  " & WScript.ScriptName & " Mapping" & VbCrLf _
		& "" & VbCrLf _
		& "  Mapping   Number of the mapping." 
	WScript.Quit
End Sub