VendorParametersSets Property of the IFPCPersist Interface

The VendorParametersSets property gets an FPCVendorParametersSets collection that can hold custom data for extending the object.

[C++]

HRESULT get_VendorParametersSets(
	IFPCVendorParametersSets** ppVendorParametersSets
);

Parameters

ppVendorParametersSets: Address of an interface pointer that on return points to an IFPCVendorParametersSets interface that represents the collection of custom data.

Return Value

This property method returns S_OK if the call is successful; otherwise, it returns an error code.

[Visual Basic]

Property VendorParametersSets As FPCVendorParametersSets

Property Value

Reference to an FPCVendorParametersSets collection that can hold custom data for extending the object.

Example Code

This VBScript script retrieves or adds the vendor parameters set for storing the parameter DontMarkSessionAsPrivateIfProxyAuthSeen to the VendorParametersSets property of the FPCArray object representing the local array and sets the value of this parameter to 1.

'Define the constants needed.
Const VpsGUID = "{143F5698-103B-12D4-FF34-1F34767DEABC}"
Const Error_FileNotFound = &H80070002
' Create the root object.
Dim root ' The FPCLib.FPC root object
Set root = CreateObject("FPC.Root")
' Declare the other objects that are required.
Dim isaArray  ' An FPCArray object
Dim vpSets	' An FPCVendorParametersSets collection
Dim vpSet	 ' An FPCVendorParametersSet object
' Obtain references to the array object
' and to the vendor parameters sets collection.
Set isaArray = root.GetContainingArray()
Set vpSets = isaArray.VendorParametersSets
' Try to retrieve the required vendor parameters set.
' If it does not exist, create it.
On Error Resume Next
Set vpSet = vpSets.Item(VpsGUID)
If Err.Number = Error_FileNotFound Then
	Err.Clear
	WScript.Echo "Creating the required vendor parameters set..."
	Set vpSet = vpSets.Add(VpsGUID)
	If Err.Number <> 0 Then
		WScript.Echo "An error occurred: 0x" & Hex(Err.Number) & " " & Err.Description
		WScript.Quit
	End If
Else
	WScript.Echo "The vendor required parameters set already exists."
End If
Err.Clear
On Error GoTo 0
' Set the value of the parameter.
vpSet.Value("DontMarkSessionAsPrivateIfProxyAuthSeen") = 1
isaArray.Save
WScript.Echo "Done!"

Remarks

This property is read-only. It can be modified by modifying the FPCVendorParametersSets collection retrieved (the IFPCVendorParametersSets interface retrieved in C++).

Requirements

Client	Requires Windows Vista or Windows XP.
Server	Requires Windows Server 2008.
Version	Requires Forefront Threat Management Gateway (TMG).
IDL	Declared in Msfpccom.idl.
DLL	Requires Msfpccom.dll.